1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4
5# This module is shared by multiple languages; use include blocker.
6if(__WINDOWS_COMPILER_PGI)
7  return()
8endif()
9set(__WINDOWS_COMPILER_PGI 1)
10
11# PGI on Windows doesn't support parallel compile processes
12if(NOT DEFINED CMAKE_JOB_POOL_LINK OR NOT DEFINED CMAKE_JOB_POOL_COMPILE OR NOT DEFINED CMAKE_JOB_POOL_PRECOMPILE_HEADER)
13  set(CMAKE_JOB_POOL_LINK PGITaskPool)
14  set(CMAKE_JOB_POOL_COMPILE PGITaskPool)
15  set(CMAKE_JOB_POOL_PRECOMPILE_HEADER PGITaskPool)
16  get_property(_pgijp GLOBAL PROPERTY JOB_POOLS)
17  if(NOT _pgijp MATCHES "PGITaskPool=")
18      set_property(GLOBAL APPEND PROPERTY JOB_POOLS PGITaskPool=1)
19  endif()
20  unset(_pgijp)
21endif()
22
23set(CMAKE_SUPPORT_WINDOWS_EXPORT_ALL_SYMBOLS 1)
24set(CMAKE_LINK_DEF_FILE_FLAG "-def:")
25# The link flags for PGI are the raw filename to add a file
26# and the UNIX -L syntax to link directories.
27set(CMAKE_LINK_LIBRARY_FLAG "")
28set(CMAKE_LINK_STARTFILE "pgimain[mx][xpt]+[.]obj")
29
30# Default to Debug builds, mirroring Windows-MSVC behavior
31set(CMAKE_BUILD_TYPE_INIT Debug)
32
33if(CMAKE_VERBOSE_MAKEFILE)
34  set(CMAKE_CL_NOLOGO)
35else()
36  set(CMAKE_CL_NOLOGO "/nologo")
37endif()
38
39macro(__windows_compiler_pgi lang)
40  # Shared library compile and link rules.
41  set(CMAKE_${lang}_CREATE_STATIC_LIBRARY "lib ${CMAKE_CL_NOLOGO} <LINK_FLAGS> /out:<TARGET> <OBJECTS> ")
42  set(CMAKE_${lang}_CREATE_SHARED_LIBRARY "<CMAKE_${lang}_COMPILER> ${CMAKE_START_TEMP_FILE} -Mmakedll -implib:<TARGET_IMPLIB> -Xlinker -pdb:<TARGET_PDB> -Xlinker -version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <LINK_FLAGS> -o <TARGET> <OBJECTS> <LINK_LIBRARIES> ${CMAKE_END_TEMP_FILE}")
43  set(CMAKE_${lang}_CREATE_SHARED_MODULE "${CMAKE_${lang}_CREATE_SHARED_LIBRARY}")
44  set(CMAKE_${lang}_LINK_EXECUTABLE "<CMAKE_${lang}_COMPILER> ${CMAKE_START_TEMP_FILE} -implib:<TARGET_IMPLIB> -Xlinker -pdb:<TARGET_PDB> -Xlinker -version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <FLAGS> <CMAKE_${lang}_LINK_FLAGS> <LINK_FLAGS> -o <TARGET> <OBJECTS> <LINK_LIBRARIES> ${CMAKE_END_TEMP_FILE}")
45
46  if("${lang}" MATCHES "C|CXX")
47    set(CMAKE_${lang}_STANDARD_LIBRARIES_INIT "kernel32.lib user32.lib gdi32.lib winspool.lib shell32.lib ole32.lib oleaut32.lib uuid.lib comdlg32.lib advapi32.lib")
48  endif()
49endmacro()
50