1@echo off
2setlocal
3set D=%~dp0
4set PCBUILD=%D%..\..\PCbuild\
5
6set BUILDX86=
7set BUILDX64=
8set BUILDARM64=
9set BUILDDOC=
10set BUILDTEST=
11set BUILDPACK=
12set REBUILD=
13
14:CheckOpts
15if    "%~1" EQU "-h" goto Help
16if /I "%~1" EQU "-x86" (set BUILDX86=1) && shift && goto CheckOpts
17if /I "%~1" EQU "-Win32" (set BUILDX86=1) && shift && goto CheckOpts
18if /I "%~1" EQU "-x64" (set BUILDX64=1) && shift && goto CheckOpts
19if /I "%~1" EQU "-arm64" (set BUILDARM64=1) && shift && goto CheckOpts
20if    "%~1" EQU "--doc" (set BUILDDOC=1) && shift && goto CheckOpts
21if    "%~1" EQU "--no-test-marker" (set BUILDTEST=) && shift && goto CheckOpts
22if    "%~1" EQU "--test-marker" (set BUILDTEST=--test-marker) && shift && goto CheckOpts
23if    "%~1" EQU "--pack" (set BUILDPACK=1) && shift && goto CheckOpts
24if    "%~1" EQU "-r" (set REBUILD=-r) && shift && goto CheckOpts
25
26if not defined BUILDX86 if not defined BUILDX64 if not defined BUILDARM64 (set BUILDX86=1) && (set BUILDX64=1)
27
28call "%D%get_externals.bat"
29call "%PCBUILD%find_msbuild.bat" %MSBUILD%
30if ERRORLEVEL 1 (echo Cannot locate MSBuild.exe on PATH or as MSBUILD variable & exit /b 2)
31
32if defined BUILDX86 (
33    call "%PCBUILD%build.bat" -p Win32 -d -e %REBUILD% %BUILDTEST%
34    if errorlevel 1 exit /B %ERRORLEVEL%
35    call "%PCBUILD%build.bat" -p Win32 -e %REBUILD% %BUILDTEST%
36    if errorlevel 1 exit /B %ERRORLEVEL%
37)
38if defined BUILDX64 (
39    call "%PCBUILD%build.bat" -p x64 -d -e %REBUILD% %BUILDTEST%
40    if errorlevel 1 exit /B %ERRORLEVEL%
41    call "%PCBUILD%build.bat" -p x64 -e %REBUILD% %BUILDTEST%
42    if errorlevel 1 exit /B %ERRORLEVEL%
43)
44if defined BUILDARM64 (
45    call "%PCBUILD%build.bat" -p ARM64 -d -e %REBUILD% %BUILDTEST%
46    if errorlevel 1 exit /B %ERRORLEVEL%
47    call "%PCBUILD%build.bat" -p ARM64 -e %REBUILD% %BUILDTEST%
48    if errorlevel 1 exit /B %ERRORLEVEL%
49)
50
51if defined BUILDDOC (
52    call "%PCBUILD%..\Doc\make.bat" html
53    if errorlevel 1 exit /B %ERRORLEVEL%
54)
55
56rem Build the launcher MSI separately
57%MSBUILD% "%D%launcher\launcher.wixproj" /p:Platform=x86
58if errorlevel 1 exit /B %ERRORLEVEL%
59
60set BUILD_CMD="%D%bundle\snapshot.wixproj"
61if defined BUILDTEST (
62    set BUILD_CMD=%BUILD_CMD% /p:UseTestMarker=true
63)
64if defined BUILDPACK (
65    set BUILD_CMD=%BUILD_CMD% /p:Pack=true
66)
67if defined REBUILD (
68    set BUILD_CMD=%BUILD_CMD% /t:Rebuild
69)
70
71if defined BUILDX86 (
72    %MSBUILD% /p:Platform=x86 %BUILD_CMD%
73    if errorlevel 1 exit /B %ERRORLEVEL%
74)
75if defined BUILDX64 (
76    %MSBUILD% /p:Platform=x64 %BUILD_CMD%
77    if errorlevel 1 exit /B %ERRORLEVEL%
78)
79if defined BUILDARM64 (
80    %MSBUILD% /p:Platform=ARM64 %BUILD_CMD%
81    if errorlevel 1 exit /B %ERRORLEVEL%
82)
83
84exit /B 0
85
86:Help
87echo build.bat [-x86] [-x64] [-arm64] [--doc] [-h] [--test-marker] [--pack] [-r]
88echo.
89echo    -x86                Build x86 installers
90echo    -x64                Build x64 installers
91echo    -ARM64              Build ARM64 installers
92echo    --doc               Build documentation
93echo    --test-marker       Build with test markers
94echo    --no-test-marker    Build without test markers (default)
95echo    --pack              Embed core MSIs into installer
96echo    -r                  Rebuild rather than incremental build
97