1# Copyright (c) 2015-2016 The Khronos Group Inc.
2#
3# Licensed under the Apache License, Version 2.0 (the "License");
4# you may not use this file except in compliance with the License.
5# You may obtain a copy of the License at
6#
7#     http://www.apache.org/licenses/LICENSE-2.0
8#
9# Unless required by applicable law or agreed to in writing, software
10# distributed under the License is distributed on an "AS IS" BASIS,
11# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
12# See the License for the specific language governing permissions and
13# limitations under the License.
14
15if (NOT ${SPIRV_SKIP_EXECUTABLES})
16 add_subdirectory(lesspipe)
17endif()
18add_subdirectory(emacs)
19
20# Add a SPIR-V Tools command line tool. Signature:
21#   add_spvtools_tool(
22#     TARGET target_name
23#     SRCS   src_file1.cpp src_file2.cpp
24#     LIBS   lib_target1 lib_target2
25#   )
26function(add_spvtools_tool)
27  set(one_value_args TARGET)
28  set(multi_value_args SRCS LIBS)
29  cmake_parse_arguments(
30    ARG "" "${one_value_args}" "${multi_value_args}" ${ARGN})
31
32  add_executable(${ARG_TARGET} ${ARG_SRCS})
33  spvtools_default_compile_options(${ARG_TARGET})
34  target_link_libraries(${ARG_TARGET} PRIVATE ${ARG_LIBS})
35  target_include_directories(${ARG_TARGET} PRIVATE
36    ${spirv-tools_SOURCE_DIR}
37    ${spirv-tools_BINARY_DIR}
38  )
39  set_property(TARGET ${ARG_TARGET} PROPERTY FOLDER "SPIRV-Tools executables")
40endfunction()
41
42set(COMMON_TOOLS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/util/flags.cpp")
43
44if (NOT ${SPIRV_SKIP_EXECUTABLES})
45  add_spvtools_tool(TARGET spirv-diff SRCS ${COMMON_TOOLS_SRCS} diff/diff.cpp util/cli_consumer.cpp LIBS SPIRV-Tools-diff SPIRV-Tools-opt ${SPIRV_TOOLS_FULL_VISIBILITY})
46  add_spvtools_tool(TARGET spirv-dis  SRCS ${COMMON_TOOLS_SRCS} dis/dis.cpp LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
47  add_spvtools_tool(TARGET spirv-val  SRCS ${COMMON_TOOLS_SRCS} val/val.cpp util/cli_consumer.cpp LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
48  add_spvtools_tool(TARGET spirv-opt  SRCS ${COMMON_TOOLS_SRCS} opt/opt.cpp util/cli_consumer.cpp LIBS SPIRV-Tools-opt ${SPIRV_TOOLS_FULL_VISIBILITY})
49  if(NOT (${CMAKE_SYSTEM_NAME} STREQUAL "iOS")) # iOS does not allow std::system calls which spirv-reduce requires
50    add_spvtools_tool(TARGET spirv-reduce SRCS ${COMMON_TOOLS_SRCS} reduce/reduce.cpp util/cli_consumer.cpp LIBS SPIRV-Tools-reduce ${SPIRV_TOOLS_FULL_VISIBILITY})
51  endif()
52  add_spvtools_tool(TARGET spirv-link SRCS ${COMMON_TOOLS_SRCS} link/linker.cpp LIBS SPIRV-Tools-link ${SPIRV_TOOLS_FULL_VISIBILITY})
53  add_spvtools_tool(TARGET spirv-lint SRCS ${COMMON_TOOLS_SRCS} lint/lint.cpp util/cli_consumer.cpp LIBS SPIRV-Tools-lint SPIRV-Tools-opt ${SPIRV_TOOLS_FULL_VISIBILITY})
54  add_spvtools_tool(TARGET spirv-as
55                    SRCS as/as.cpp
56                         ${COMMON_TOOLS_SRCS}
57                    LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
58  target_include_directories(spirv-as PRIVATE ${spirv-tools_SOURCE_DIR}
59                                              ${SPIRV_HEADER_INCLUDE_DIR})
60  add_spvtools_tool(TARGET spirv-cfg
61                    SRCS cfg/cfg.cpp
62                         cfg/bin_to_dot.h
63                         cfg/bin_to_dot.cpp
64                         ${COMMON_TOOLS_SRCS}
65                    LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
66  target_include_directories(spirv-cfg PRIVATE ${spirv-tools_SOURCE_DIR}
67                                               ${SPIRV_HEADER_INCLUDE_DIR})
68  set(SPIRV_INSTALL_TARGETS spirv-as spirv-dis spirv-val spirv-opt
69                            spirv-cfg spirv-link spirv-lint)
70
71  if(NOT (${CMAKE_SYSTEM_NAME} STREQUAL "Android"))
72    add_spvtools_tool(TARGET spirv-objdump
73                      SRCS objdump/objdump.cpp
74                           objdump/extract_source.cpp
75                           util/cli_consumer.cpp
76                           ${COMMON_TOOLS_SRCS}
77                      LIBS ${SPIRV_TOOLS_FULL_VISIBILITY})
78    target_include_directories(spirv-objdump PRIVATE ${spirv-tools_SOURCE_DIR}
79                                                     ${SPIRV_HEADER_INCLUDE_DIR})
80    set(SPIRV_INSTALL_TARGETS ${SPIRV_INSTALL_TARGETS} spirv-objdump)
81  endif()
82
83  if(NOT (${CMAKE_SYSTEM_NAME} STREQUAL "iOS"))
84    set(SPIRV_INSTALL_TARGETS ${SPIRV_INSTALL_TARGETS} spirv-reduce)
85  endif()
86
87  if(SPIRV_BUILD_FUZZER)
88    add_spvtools_tool(TARGET spirv-fuzz SRCS fuzz/fuzz.cpp util/cli_consumer.cpp LIBS SPIRV-Tools-fuzz ${SPIRV_TOOLS_FULL_VISIBILITY})
89    set(SPIRV_INSTALL_TARGETS ${SPIRV_INSTALL_TARGETS} spirv-fuzz)
90  endif(SPIRV_BUILD_FUZZER)
91
92  if(ENABLE_SPIRV_TOOLS_INSTALL)
93    install(TARGETS ${SPIRV_INSTALL_TARGETS} EXPORT SPIRV-Tools-toolsTargets)
94    export(EXPORT SPIRV-Tools-toolsTargets FILE SPIRV-Tools-toolsTargets.cmake)
95
96    spvtools_config_package_dir(SPIRV-Tools-tools PACKAGE_DIR)
97    install(EXPORT SPIRV-Tools-toolsTargets FILE SPIRV-Tools-toolsTargets.cmake
98            DESTINATION ${PACKAGE_DIR})
99
100    file(WRITE ${CMAKE_BINARY_DIR}/SPIRV-Tools-toolsConfig.cmake
101      "include(CMakeFindDependencyMacro)\n"
102      "find_dependency(${SPIRV_TOOLS})\n"
103      "include(\${CMAKE_CURRENT_LIST_DIR}/SPIRV-Tools-toolsTargets.cmake)\n"
104      )
105
106    install(FILES ${CMAKE_BINARY_DIR}/SPIRV-Tools-toolsConfig.cmake DESTINATION ${PACKAGE_DIR})
107  endif(ENABLE_SPIRV_TOOLS_INSTALL)
108endif()
109