1# Copyright (c) 2015-2024 The Khronos Group Inc.
2#
3# Permission is hereby granted, free of charge, to any person obtaining a
4# copy of this software and/or associated documentation files (the
5# "Materials"), to deal in the Materials without restriction, including
6# without limitation the rights to use, copy, modify, merge, publish,
7# distribute, sublicense, and/or sell copies of the Materials, and to
8# permit persons to whom the Materials are furnished to do so, subject to
9# the following conditions:
10#
11# The above copyright notice and this permission notice shall be included
12# in all copies or substantial portions of the Materials.
13#
14# MODIFICATIONS TO THIS FILE MAY MEAN IT NO LONGER ACCURATELY REFLECTS
15# KHRONOS STANDARDS. THE UNMODIFIED, NORMATIVE VERSIONS OF KHRONOS
16# SPECIFICATIONS AND HEADER INFORMATION ARE LOCATED AT
17#    https://www.khronos.org/registry/
18#
19# THE MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
20# EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
21# MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
22# IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
23# CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
24# TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
25# MATERIALS OR THE USE OR OTHER DEALINGS IN THE MATERIALS.
26cmake_minimum_required(VERSION 3.14)
27project(SPIRV-Headers LANGUAGES CXX VERSION 1.5.5)
28
29if (CMAKE_VERSION VERSION_LESS "3.21")
30    # https://cmake.org/cmake/help/latest/variable/PROJECT_IS_TOP_LEVEL.html
31    string(COMPARE EQUAL ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} PROJECT_IS_TOP_LEVEL)
32endif()
33
34add_library(SPIRV-Headers INTERFACE)
35add_library(SPIRV-Headers::SPIRV-Headers ALIAS SPIRV-Headers)
36target_include_directories(SPIRV-Headers INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
37
38if (PROJECT_IS_TOP_LEVEL)
39    option(BUILD_TESTS "Build the tests")
40    if (BUILD_TESTS)
41        add_subdirectory(tests)
42    endif()
43
44    include(GNUInstallDirs)
45    include(CMakePackageConfigHelpers)
46
47    install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
48
49    set(cmake_install_dir "${CMAKE_INSTALL_DATADIR}/cmake/SPIRV-Headers")
50    set(version_config "${CMAKE_CURRENT_BINARY_DIR}/generated/SPIRV-HeadersConfigVersion.cmake")
51
52    write_basic_package_version_file("${version_config}" COMPATIBILITY SameMajorVersion ARCH_INDEPENDENT)
53    install(FILES "${version_config}" DESTINATION "${cmake_install_dir}")
54
55    install(TARGETS SPIRV-Headers EXPORT "SPIRV-HeadersConfig" INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
56    install(EXPORT "SPIRV-HeadersConfig" NAMESPACE "SPIRV-Headers::" DESTINATION "${cmake_install_dir}")
57
58    if (IS_ABSOLUTE ${CMAKE_INSTALL_INCLUDEDIR})
59        set(SPIRV_HEADERS_PKGCONFIG_INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR})
60    else()
61        set(SPIRV_HEADERS_PKGCONFIG_INCLUDE_DIR ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR})
62    endif()
63    configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/SPIRV-Headers.pc.in ${CMAKE_CURRENT_BINARY_DIR}/SPIRV-Headers.pc @ONLY)
64    install(FILES "${CMAKE_CURRENT_BINARY_DIR}/SPIRV-Headers.pc" DESTINATION ${CMAKE_INSTALL_DATADIR}/pkgconfig)
65endif()
66