xref: /libbtbb/lib/src/CMakeLists.txt (revision ad7b9457824d19338344c51bf91c59873809f1ba)

#
# This file is part of Libbtbb.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; see the file COPYING.  If not, write to
# the Free Software Foundation, Inc., 51 Franklin Street,
# Boston, MA 02110-1301, USA.
#
# Based slightly upon the hackrf cmake setup.

# FIXME Set static release version here to avoid pulling from git
set(RELEASE "")
set(DIRTY_FLAG "")

if ( "${RELEASE}" STREQUAL "" )
	# automatic git version when working out of git
	include(GetGitRevisionDescription)
	get_git_head_revision(GIT_REFSPEC RELEASE)

	execute_process(COMMAND git status -s --untracked-files=no OUTPUT_VARIABLE DIRTY)
	if ( NOT "${DIRTY}" STREQUAL "" )
		set(DIRTY_FLAG "*")
	endif()
endif()

add_definitions( -DRELEASE="${RELEASE}${DIRTY_FLAG}" )

# Source
set(c_sources ${CMAKE_CURRENT_SOURCE_DIR}/bluetooth_packet.c
              ${CMAKE_CURRENT_SOURCE_DIR}/bluetooth_piconet.c
              ${CMAKE_CURRENT_SOURCE_DIR}/bluetooth_le_packet.c
              ${CMAKE_CURRENT_SOURCE_DIR}/pcap.c
              ${CMAKE_CURRENT_SOURCE_DIR}/pcapng.c
              ${CMAKE_CURRENT_SOURCE_DIR}/pcapng-bt.c
			  CACHE INTERNAL "List of C sources")
set(c_headers ${CMAKE_CURRENT_SOURCE_DIR}/btbb.h
			  CACHE INTERNAL "List of C headers")

# Defaults: BUILD_SHARED=ON, BUILD_STATIC=OFF
if( NOT DEFINED BUILD_SHARED )
	set(BUILD_SHARED ON)
endif( NOT DEFINED BUILD_SHARED )
if( NOT DEFINED BUILD_STATIC )
	set(BUILD_STATIC OFF)
endif( NOT DEFINED BUILD_STATIC )

if( NOT ${BUILD_SHARED} AND NOT ${BUILD_STATIC} )
	message( FATAL_ERROR "Not building static or shared library - at least one must be built")
endif( NOT ${BUILD_SHARED} AND NOT ${BUILD_STATIC} )

if( ${BUILD_SHARED} )
	# Shared library
	message(STATUS "Building shared library")
	add_library(btbb SHARED ${c_sources})
	set_target_properties(btbb PROPERTIES VERSION ${MAJOR_VERSION}.${MINOR_VERSION} SOVERSION 0)
	set_target_properties(btbb PROPERTIES CLEAN_DIRECT_OUTPUT 1)
endif( ${BUILD_SHARED} )

if( ${BUILD_STATIC} )
	# Static library
	message(STATUS "Building static library")
	add_library(btbb-static STATIC ${c_sources})
	set_target_properties(btbb-static PROPERTIES OUTPUT_NAME "btbb")
	set_target_properties(btbb-static PROPERTIES CLEAN_DIRECT_OUTPUT 1)
endif( ${BUILD_STATIC} )

# PCAP Support
if( (NOT DEFINED USE_PCAP) OR USE_PCAP )
	find_package(PCAP)

	if( USE_PCAP AND NOT ${PCAP_FOUND} )
		message( FATAL_ERROR
			"Cannot find libpcap, which is required for USE_PCAP")
	endif()

	if( ${PCAP_FOUND} )
		include_directories(${PCAP_INCLUDE_DIRS})
		if( ${BUILD_SHARED} )
			target_link_libraries(btbb ${PCAP_LIBRARIES})
		endif( ${BUILD_SHARED} )
		if( ${BUILD_STATIC} )
			target_link_libraries(btbb-static ${PCAP_LIBRARIES})
		endif( ${BUILD_STATIC} )
		add_definitions( -DENABLE_PCAP )
	endif( ${PCAP_FOUND} )
endif( (NOT DEFINED USE_PCAP) OR USE_PCAP )

if( ${BUILD_SHARED} )
   install(TARGETS btbb
           LIBRARY DESTINATION lib${LIB_SUFFIX}
           COMPONENT sharedlibs
           )
endif( ${BUILD_SHARED} )

if( ${BUILD_STATIC} )
   install(TARGETS btbb-static
           DESTINATION bin
           COMPONENT staticlibs
           )
endif( ${BUILD_STATIC} )

install(FILES ${c_headers}
        DESTINATION include
        COMPONENT headers
        )