xref: /aosp_15_r20/external/pigweed/third_party/mbedtls/BUILD.gn (revision 61c4878ac05f98d0ceed94b57d316916de578985)

# Copyright 2021 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")
import("$dir_pw_build/target_types.gni")
import("$dir_pw_toolchain/generate_toolchain.gni")
import("mbedtls.gni")

if (dir_pw_third_party_mbedtls != "") {
  # All source files for mbedtls-2.26.0 released on 2021-03-12
  mbedtls_v2_sources = [
    "library/aes.c",
    "library/aesni.c",
    "library/arc4.c",
    "library/aria.c",
    "library/asn1parse.c",
    "library/asn1write.c",
    "library/base64.c",
    "library/bignum.c",
    "library/blowfish.c",
    "library/camellia.c",
    "library/ccm.c",
    "library/certs.c",
    "library/chacha20.c",
    "library/chachapoly.c",
    "library/cipher.c",
    "library/cipher_wrap.c",
    "library/cmac.c",
    "library/ctr_drbg.c",
    "library/debug.c",
    "library/des.c",
    "library/dhm.c",
    "library/ecdh.c",
    "library/ecdsa.c",
    "library/ecjpake.c",
    "library/ecp.c",
    "library/ecp_curves.c",
    "library/entropy.c",
    "library/entropy_poll.c",
    "library/error.c",
    "library/gcm.c",
    "library/havege.c",
    "library/hkdf.c",
    "library/hmac_drbg.c",
    "library/md.c",
    "library/md2.c",
    "library/md4.c",
    "library/md5.c",
    "library/memory_buffer_alloc.c",
    "library/net_sockets.c",
    "library/nist_kw.c",
    "library/oid.c",
    "library/padlock.c",
    "library/pem.c",
    "library/pk.c",
    "library/pk_wrap.c",
    "library/pkcs11.c",
    "library/pkcs12.c",
    "library/pkcs5.c",
    "library/pkparse.c",
    "library/pkwrite.c",
    "library/platform.c",
    "library/platform_util.c",
    "library/poly1305.c",
    "library/psa_crypto.c",
    "library/psa_crypto_driver_wrappers.c",
    "library/psa_crypto_se.c",
    "library/psa_crypto_slot_management.c",
    "library/psa_crypto_storage.c",
    "library/psa_its_file.c",
    "library/ripemd160.c",
    "library/rsa.c",
    "library/rsa_internal.c",
    "library/sha1.c",
    "library/sha256.c",
    "library/sha512.c",
    "library/ssl_cache.c",
    "library/ssl_ciphersuites.c",
    "library/ssl_cli.c",
    "library/ssl_cookie.c",
    "library/ssl_msg.c",
    "library/ssl_srv.c",
    "library/ssl_ticket.c",
    "library/ssl_tls.c",
    "library/ssl_tls13_keys.c",
    "library/threading.c",
    "library/timing.c",
    "library/version.c",
    "library/version_features.c",
    "library/x509.c",
    "library/x509_create.c",
    "library/x509_crl.c",
    "library/x509_crt.c",
    "library/x509_csr.c",
    "library/x509write_crt.c",
    "library/x509write_csr.c",
    "library/xtea.c",
  ]

  # All source files for mbedtls-3.2.1 released on 2022-07-12
  mbedtls_v3_sources = [
    "library/aes.c",
    "library/aesce.c",
    "library/aesni.c",
    "library/aria.c",
    "library/asn1parse.c",
    "library/asn1write.c",
    "library/base64.c",
    "library/bignum.c",
    "library/bignum_core.c",
    "library/bignum_mod.c",
    "library/bignum_mod_raw.c",
    "library/camellia.c",
    "library/ccm.c",
    "library/chacha20.c",
    "library/chachapoly.c",
    "library/cipher.c",
    "library/cipher_wrap.c",
    "library/cmac.c",
    "library/constant_time.c",
    "library/ctr_drbg.c",
    "library/debug.c",
    "library/des.c",
    "library/dhm.c",
    "library/ecdh.c",
    "library/ecdsa.c",
    "library/ecjpake.c",
    "library/ecp.c",
    "library/ecp_curves.c",
    "library/ecp_curves_new.c",
    "library/entropy.c",
    "library/entropy_poll.c",
    "library/error.c",
    "library/gcm.c",
    "library/hkdf.c",
    "library/hmac_drbg.c",
    "library/lmots.c",
    "library/lms.c",
    "library/md.c",
    "library/md5.c",
    "library/memory_buffer_alloc.c",
    "library/mps_reader.c",
    "library/mps_trace.c",
    "library/net_sockets.c",
    "library/nist_kw.c",
    "library/oid.c",
    "library/padlock.c",
    "library/pem.c",
    "library/pk.c",
    "library/pk_wrap.c",
    "library/pkcs12.c",
    "library/pkcs5.c",
    "library/pkcs7.c",
    "library/pkparse.c",
    "library/pkwrite.c",
    "library/platform.c",
    "library/platform_util.c",
    "library/poly1305.c",
    "library/psa_crypto.c",
    "library/psa_crypto_aead.c",
    "library/psa_crypto_cipher.c",
    "library/psa_crypto_client.c",
    "library/psa_crypto_driver_wrappers_no_static.c",
    "library/psa_crypto_ecp.c",
    "library/psa_crypto_ffdh.c",
    "library/psa_crypto_hash.c",
    "library/psa_crypto_mac.c",
    "library/psa_crypto_pake.c",
    "library/psa_crypto_rsa.c",
    "library/psa_crypto_se.c",
    "library/psa_crypto_slot_management.c",
    "library/psa_crypto_storage.c",
    "library/psa_its_file.c",
    "library/psa_util.c",
    "library/ripemd160.c",
    "library/rsa.c",
    "library/rsa_alt_helpers.c",
    "library/sha1.c",
    "library/sha256.c",
    "library/sha3.c",
    "library/sha512.c",
    "library/ssl_cache.c",
    "library/ssl_ciphersuites.c",
    "library/ssl_client.c",
    "library/ssl_cookie.c",
    "library/ssl_debug_helpers_generated.c",
    "library/ssl_msg.c",
    "library/ssl_ticket.c",
    "library/ssl_tls.c",
    "library/ssl_tls12_client.c",
    "library/ssl_tls12_server.c",
    "library/ssl_tls13_client.c",
    "library/ssl_tls13_generic.c",
    "library/ssl_tls13_keys.c",
    "library/ssl_tls13_server.c",
    "library/threading.c",
    "library/timing.c",
    "library/version.c",
    "library/version_features.c",
    "library/x509.c",
    "library/x509_create.c",
    "library/x509_crl.c",
    "library/x509_crt.c",
    "library/x509_csr.c",
    "library/x509write.c",
    "library/x509write_crt.c",
    "library/x509write_csr.c",
  ]

  config("public_config") {
    include_dirs = [ "$dir_pw_third_party_mbedtls/include" ]
  }

  config("internal_config") {
    include_dirs = [
      "$dir_pw_third_party_mbedtls",
      "$dir_pw_third_party_mbedtls/include",
      "$dir_pw_third_party/mbedtls",
    ]
    cflags = [
      "-Wno-error=cast-qual",
      "-Wno-error=redundant-decls",
      "-Wno-error=implicit-function-declaration",
      "-w",
    ]
    config_header_file = rebase_path(pw_third_party_mbedtls_CONFIG_HEADER,
                                     get_label_info(":mbedtls", "dir"))
    defines = [ "MBEDTLS_CONFIG_FILE=\"$config_header_file\"" ]
    if (defined(pw_toolchain_SCOPE.is_host_toolchain) &&
        pw_toolchain_SCOPE.is_host_toolchain) {
      defines += [ "_PW_MBEDTLS_IS_HOST=1" ]
    } else {
      defines += [ "_PW_MBEDTLS_IS_HOST=0" ]
    }
  }

  pw_source_set("mbedtls") {
    # Skip gn check because downstream users may choose either but not
    # both ":mbedtls" and ":mbedtls_v3" depending on if the underlying
    # mbedtls git is 2.x or 3.x.
    check_includes = false
    sources = []
    foreach(source, mbedtls_v2_sources) {
      sources += [ "$dir_pw_third_party_mbedtls/" + source ]
    }

    public = [
      "configs/config_default.h",
      "configs/config_pigweed_common.h",
    ]

    public_deps = [ "$dir_pw_tls_client:time" ]
    public_configs = [ ":public_config" ]
    configs = [ ":internal_config" ]
  }

  pw_source_set("mbedtls_v3") {
    # Skip gn check because downstream users may choose either but not
    # both ":mbedtls" and ":mbedtls_v3" depending on if the underlying
    # mbedtls git is 2.x or 3.x.
    check_includes = false
    sources = []
    foreach(source, mbedtls_v3_sources) {
      sources += [ "$dir_pw_third_party_mbedtls/" + source ]
    }

    public = [
      "configs/config_default.h",
      "configs/config_pigweed_common.h",
    ]

    public_deps = [ "$dir_pw_tls_client:time" ]
    public_configs = [ ":public_config" ]
    configs = [ ":internal_config" ]
  }
} else {
  group("mbedtls") {
  }

  group("mbedtls_v3") {
  }
}