xref: /aosp_15_r20/external/pigweed/pw_varint/BUILD.gn (revision 61c4878ac05f98d0ceed94b57d316916de578985)

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_fuzzer/fuzz_test.gni")
import("$dir_pw_unit_test/test.gni")

config("default_config") {
  include_dirs = [ "public" ]
}

pw_source_set("pw_varint") {
  public_configs = [ ":default_config" ]
  public_deps = [
    "$dir_pw_third_party/fuchsia:stdcompat",
    dir_pw_preprocessor,
    dir_pw_span,
  ]
  sources = [
    "varint.cc",
    "varint_c.c",
  ]
  public = [ "public/pw_varint/varint.h" ]

  # TODO: b/259746255 - Remove this when everything compiles with -Wconversion.
  configs = [ "$dir_pw_build:conversion_warnings" ]
}

pw_source_set("stream") {
  public_configs = [ ":default_config" ]
  public_deps = [
    dir_pw_status,
    dir_pw_stream,
  ]
  public = [ "public/pw_varint/stream.h" ]
  sources = [ "stream.cc" ]
  deps = [
    ":pw_varint",
    dir_pw_span,
  ]
}

pw_test_group("tests") {
  tests = [
    ":stream_test",
    ":varint_test",
  ]
}

pw_fuzz_test("varint_test") {
  deps = [ ":pw_varint" ]
  sources = [
    "varint_test.cc",
    "varint_test_c.c",
  ]

  # TODO: b/259746255 - Remove this when everything compiles with -Wconversion.
  configs = [ "$dir_pw_build:conversion_warnings" ]
}

pw_test("stream_test") {
  deps = [
    ":pw_varint",
    ":stream",
    dir_pw_stream,
  ]
  sources = [ "stream_test.cc" ]

  # TODO: b/259746255 - Remove this when everything compiles with -Wconversion.
  configs = [ "$dir_pw_build:conversion_warnings" ]
}

pw_doc_group("docs") {
  inputs = [ "Kconfig" ]
  sources = [ "docs.rst" ]
}