xref: /aosp_15_r20/external/pigweed/pw_hdlc/rpc_example/BUILD.gn (revision 61c4878ac05f98d0ceed94b57d316916de578985)

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/python.gni")
import("$dir_pw_build/target_types.gni")
import("$dir_pw_rpc/system_server/backend.gni")
import("$dir_pw_third_party/nanopb/nanopb.gni")

if (dir_pw_third_party_nanopb == "" || pw_rpc_system_server_BACKEND == "") {
  group("rpc_example") {
  }
} else {
  pw_executable("rpc_example") {
    sources = [
      "hdlc_rpc_server.cc",
      "main.cc",
    ]
    deps = [
      "$dir_pw_rpc:server",
      "$dir_pw_rpc/nanopb:echo_service",
      "$dir_pw_rpc/system_server",
      "..:default_addresses",
      dir_pw_hdlc,
      dir_pw_log,
    ]
  }
}

pw_python_script("example_script") {
  sources = [ "example_script.py" ]
  python_deps = [
    "$dir_pw_build/py",
    "$dir_pw_hdlc/py",
    "$dir_pw_log:protos.python",
    "$dir_pw_tokenizer/py:test_proto.python",
  ]
  pylintrc = "$dir_pigweed/.pylintrc"
  mypy_ini = "$dir_pigweed/.mypy.ini"
  ruff_toml = "$dir_pigweed/.ruff.toml"
}