xref: /aosp_15_r20/external/opencensus-java/contrib/appengine_standard_util/build.gradle (revision a24ffb47c3166327784aa05b149974e82e8f71b8)

description = 'OpenCensus AppEngine Standard Util'

apply plugin: 'java'
apply plugin: 'com.google.protobuf'

def protocVersion = '3.11.4'

buildscript {
    repositories {
        maven { url "https://plugins.gradle.org/m2/" }
    }
    dependencies {
        classpath "com.google.protobuf:protobuf-gradle-plugin:0.8.8"
    }
}

[compileJava, compileTestJava].each() {
    it.sourceCompatibility = 1.7
    it.targetCompatibility = 1.7
}

dependencies {
    compile project(':opencensus-api'),
            libraries.appengine_api,
            libraries.guava,
            libraries.protobuf

    signature "org.codehaus.mojo.signature:java18:+@signature"
}

protobuf {
    protoc {
        // The artifact spec for the Protobuf Compiler
        artifact = "com.google.protobuf:protoc:${protocVersion}"
    }

    generatedFilesBaseDir = "$projectDir/gen_gradle/src"

    generateProtoTasks {
        all().each { task ->
            task.builtins {
                java {
                    option 'annotate_code'
                }
            }
        }
    }
}

clean {
    delete protobuf.generatedFilesBaseDir
}